<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Package::Stash;
{
  $Package::Stash::VERSION = '0.33';
}
use strict;
use warnings;
# ABSTRACT: routines for manipulating stashes

our $IMPLEMENTATION;

BEGIN {
    $IMPLEMENTATION = $ENV{PACKAGE_STASH_IMPLEMENTATION}
        if exists $ENV{PACKAGE_STASH_IMPLEMENTATION};

    my $err;
    if ($IMPLEMENTATION) {
        if (!eval "require Package::Stash::$IMPLEMENTATION; 1") {
            require Carp;
            Carp::croak("Could not load Package::Stash::$IMPLEMENTATION: $@");
        }
    }
    else {
        for my $impl ('XS', 'PP') {
            if (eval "require Package::Stash::$impl; 1;") {
                $IMPLEMENTATION = $impl;
                last;
            }
            else {
                $err .= $@;
            }
        }
    }

    if (!$IMPLEMENTATION) {
        require Carp;
        Carp::croak("Could not find a suitable Package::Stash implementation: $err");
    }

    my $impl = "Package::Stash::$IMPLEMENTATION";
    my $from = $impl-&gt;new($impl);
    my $to = $impl-&gt;new(__PACKAGE__);
    my $methods = $from-&gt;get_all_symbols('CODE');
    for my $meth (keys %$methods) {
        $to-&gt;add_symbol("&amp;$meth" =&gt; $methods-&gt;{$meth});
    }
}

use Package::DeprecationManager -deprecations =&gt; {
    'Package::Stash::add_package_symbol'        =&gt; 0.14,
    'Package::Stash::remove_package_glob'       =&gt; 0.14,
    'Package::Stash::has_package_symbol'        =&gt; 0.14,
    'Package::Stash::get_package_symbol'        =&gt; 0.14,
    'Package::Stash::get_or_add_package_symbol' =&gt; 0.14,
    'Package::Stash::remove_package_symbol'     =&gt; 0.14,
    'Package::Stash::list_all_package_symbols'  =&gt; 0.14,
};

sub add_package_symbol {
    #deprecated('add_package_symbol is deprecated, please use add_symbol');
    shift-&gt;add_symbol(@_);
}

sub remove_package_glob {
    #deprecated('remove_package_glob is deprecated, please use remove_glob');
    shift-&gt;remove_glob(@_);
}

sub has_package_symbol {
    #deprecated('has_package_symbol is deprecated, please use has_symbol');
    shift-&gt;has_symbol(@_);
}

sub get_package_symbol {
    #deprecated('get_package_symbol is deprecated, please use get_symbol');
    shift-&gt;get_symbol(@_);
}

sub get_or_add_package_symbol {
    #deprecated('get_or_add_package_symbol is deprecated, please use get_or_add_symbol');
    shift-&gt;get_or_add_symbol(@_);
}

sub remove_package_symbol {
    #deprecated('remove_package_symbol is deprecated, please use remove_symbol');
    shift-&gt;remove_symbol(@_);
}

sub list_all_package_symbols {
    #deprecated('list_all_package_symbols is deprecated, please use list_all_symbols');
    shift-&gt;list_all_symbols(@_);
}


1;

__END__
=pod

=head1 NAME

Package::Stash - routines for manipulating stashes

=head1 VERSION

version 0.33

=head1 SYNOPSIS

  my $stash = Package::Stash-&gt;new('Foo');
  $stash-&gt;add_symbol('%foo', {bar =&gt; 1});
  # $Foo::foo{bar} == 1
  $stash-&gt;has_symbol('$foo') # false
  my $namespace = $stash-&gt;namespace;
  *{ $namespace-&gt;{foo} }{HASH} # {bar =&gt; 1}

=head1 DESCRIPTION

Manipulating stashes (Perl's symbol tables) is occasionally necessary, but
incredibly messy, and easy to get wrong. This module hides all of that behind a
simple API.

NOTE: Most methods in this class require a variable specification that includes
a sigil. If this sigil is absent, it is assumed to represent the IO slot.

Due to limitations in the typeglob API available to perl code, and to typeglob
manipulation in perl being quite slow, this module provides two
implementations - one in pure perl, and one using XS. The XS implementation is
to be preferred for most usages; the pure perl one is provided for cases where
XS modules are not a possibility. The current implementation in use can be set
by setting C&lt;$ENV{PACKAGE_STASH_IMPLEMENTATION}&gt; or
C&lt;$Package::Stash::IMPLEMENTATION&gt; before loading Package::Stash (with the
environment variable taking precedence), otherwise, it will use the XS
implementation if possible, falling back to the pure perl one.

=head1 METHODS

=head2 new $package_name

Creates a new C&lt;Package::Stash&gt; object, for the package given as the only
argument.

=head2 name

Returns the name of the package that this object represents.

=head2 namespace

Returns the raw stash itself.

=head2 add_symbol $variable $value %opts

Adds a new package symbol, for the symbol given as C&lt;$variable&gt;, and optionally
gives it an initial value of C&lt;$value&gt;. C&lt;$variable&gt; should be the name of
variable including the sigil, so

  Package::Stash-&gt;new('Foo')-&gt;add_symbol('%foo')

will create C&lt;%Foo::foo&gt;.

Valid options (all optional) are C&lt;filename&gt;, C&lt;first_line_num&gt;, and
C&lt;last_line_num&gt;.

C&lt;$opts{filename}&gt;, C&lt;$opts{first_line_num}&gt;, and C&lt;$opts{last_line_num}&gt; can
be used to indicate where the symbol should be regarded as having been defined.
Currently these values are only used if the symbol is a subroutine ('C&lt;&amp;&gt;'
sigil) and only if C&lt;$^P &amp; 0x10&gt; is true, in which case the special C&lt;%DB::sub&gt;
hash is updated to record the values of C&lt;filename&gt;, C&lt;first_line_num&gt;, and
C&lt;last_line_num&gt; for the subroutine. If these are not passed, their values are
inferred (as much as possible) from C&lt;caller&gt; information.

This is especially useful for debuggers and profilers, which use C&lt;%DB::sub&gt; to
determine where the source code for a subroutine can be found.  See
L&lt;http://perldoc.perl.org/perldebguts.html#Debugger-Internals&gt; for more
information about C&lt;%DB::sub&gt;.

=head2 remove_glob $name

Removes all package variables with the given name, regardless of sigil.

=head2 has_symbol $variable

Returns whether or not the given package variable (including sigil) exists.

=head2 get_symbol $variable

Returns the value of the given package variable (including sigil).

=head2 get_or_add_symbol $variable

Like C&lt;get_symbol&gt;, except that it will return an empty hashref or
arrayref if the variable doesn't exist.

=head2 remove_symbol $variable

Removes the package variable described by C&lt;$variable&gt; (which includes the
sigil); other variables with the same name but different sigils will be
untouched.

=head2 list_all_symbols $type_filter

Returns a list of package variable names in the package, without sigils. If a
C&lt;type_filter&gt; is passed, it is used to select package variables of a given
type, where valid types are the slots of a typeglob ('SCALAR', 'CODE', 'HASH',
etc). Note that if the package contained any C&lt;BEGIN&gt; blocks, perl will leave
an empty typeglob in the C&lt;BEGIN&gt; slot, so this will show up if no filter is
used (and similarly for C&lt;INIT&gt;, C&lt;END&gt;, etc).

=head2 get_all_symbols $type_filter

Returns a hashref, keyed by the variable names in the package. If
C&lt;$type_filter&gt; is passed, the hash will contain every variable of that type in
the package as values, otherwise, it will contain the typeglobs corresponding
to the variable names (basically, a clone of the stash).

=head1 BUGS / CAVEATS

=over 4

=item * Prior to perl 5.10, scalar slots are only considered to exist if they are defined

This is due to a shortcoming within perl itself. See
L&lt;perlref/Making References&gt; point 7 for more information.

=item * GLOB and FORMAT variables are not (yet) accessible through this module.

=item * Also, see the BUGS section for the specific backends (L&lt;Package::Stash::XS&gt; and L&lt;Package::Stash::PP&gt;)

=back

Please report any bugs through RT: email
C&lt;bug-package-stash at rt.cpan.org&gt;, or browse to
L&lt;http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Package-Stash&gt;.

=head1 SUPPORT

You can find this documentation for this module with the perldoc command.

    perldoc Package::Stash

You can also look for information at:

=over 4

=item * AnnoCPAN: Annotated CPAN documentation

L&lt;http://annocpan.org/dist/Package-Stash&gt;

=item * CPAN Ratings

L&lt;http://cpanratings.perl.org/d/Package-Stash&gt;

=item * RT: CPAN's request tracker

L&lt;http://rt.cpan.org/NoAuth/Bugs.html?Dist=Package-Stash&gt;

=item * Search CPAN

L&lt;http://search.cpan.org/dist/Package-Stash&gt;

=back

=head1 AUTHOR

Jesse Luehrs &lt;doy at tozt dot net&gt;

Based on code from L&lt;Class::MOP::Package&gt;, by Stevan Little and the Moose
Cabal.

=for Pod::Coverage add_package_symbol
remove_package_glob
has_package_symbol
get_package_symbol
get_or_add_package_symbol
remove_package_symbol
list_all_package_symbols

=head1 SEE ALSO

=over 4

=item * L&lt;Class::MOP::Package&gt;

This module is a factoring out of code that used to live here

=back

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011 by Jesse Luehrs.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut

</pre></body></html>